[bovirus]

Hi.

Could you please consider to mody the installer script to change the program name in list of program installed from

Shark MediaInfo Tool x.x.x.x (where x.x.x. is version)

to

Shark MediaInfo Tool

without info about version in program name?

"Version" is already availbale in version column.

[Shark007]

If you can figure out how to do that using INNO Setup . . .
please share that information here.

[bovirus]

Sorry but I didn't understand.

I know Inno Setup very well (I'm the official Italian translator for IS and a IS power user).

Please setup in your installer script in [Setup] section

UninstallerDisplayName=Shark's MediaInfo Tool

Thanks.

[Shark007]

Edited.

UninstallDisplayName=Shark's MediaInfo Tool

The above worked.

I replaced the current file with the new file.

[bovirus]

Hi.

Thanks.

Could you please consdier to add Italian language to the installer script?
If you add italian add this in [Setup] section of Inno Setup installer script to re-detect new language added.

ShowLanguageDialog=yes
UsePreviousLanguage=no
LanguageDetectionMethod=uilanguage

Some feedback

Installer exe file properties - File Version - Report 26.0.0 (instead 26.5.0.0)

Installer exe file properties - Copyright info is empty
See 'AppCopyright' value in Inno Setup installer script

If you like I can help with .iss file make some changes automatically.
If you agree please send me .iss file.

Thanks.

[Shark007]

I appreciate the assistance.
iss file

[bovirus]

Attached new iss tested on my configuration.

- Use of define instruction for fxed values.
- Added Italian language.
- Version automatically checked and setup by main exe file.
- Setup all URL
- Setup copyright with author and year automnatically updated.
etc.

Please test it.

#define AppName "Shark's MediaInfo"
#define AppAuthor "Shark007"
#define AppVersion() ParseVersion("{app}" + "\" + AppName + "\" + AppName + ".exe", Local[0], Local[1], Local[2], Local[3]), str(Local[0]) + "." + str(Local[1])
#define AppURL "https://shark007.net"
#define CurrentYear GetDateTimeString('yyyy','','')

[Setup]
AppId={#AppName}
AppName={#AppName}
AppVerName={#AppName} {#AppVersion}
AppVersion={#AppVersion}

VersionInfoVersion={#AppVersion}
VersionInfoDescription={#AppName} installer
VersionInfoProductName={#AppName}

AppCopyright=© {#CurrentYear} by {#AppAuthor}

AppPublisher={#AppAuthor}
AppPublisherURL={#AppURL}
AppSupportURL={#AppURL}
AppUpdatesURL={#AppURL}

UninstallDisplayName={#AppName}
UninstallDisplayIcon={app}\{#AppName}.exe

WizardImageFile=embedded\branding.bmp
WizardSmallImageFile=embedded\banner.bmp

SetupIconFile=embedded\ico.ico

WizardStyle=modern

ShowLanguageDialog=yes
UsePreviousLanguage=no
LanguageDetectionMethod=uilanguage

DefaultDirName={autopf64}\{#AppName}
DefaultGroupName={#AppName}
OutputBaseFilename=Shark's_MediaInfo_v{#AppVersion}

ArchitecturesAllowed=x64os
ArchitecturesInstallIn64BitMode=x64os
Compression=lzma2/ultra64
SolidCompression=true
PrivilegesRequired=none
DisableDirPage=auto
DisableProgramGroupPage=auto
DirExistsWarning=no

[Languages]
Name: "english"; MessagesFile: "compiler:\Default.isl";
Name: "italian"; MessagesFile: "compiler:\Languages\Italian.isl";

[CustomMessages]
english.UninstallApp=Uninstall {#AppName}

italian.UninstallApp=Disinstalla {#AppName}

[Files]
Source: "{app}\{#AppName}\{#AppName}.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "{app}\{#AppName}\MediaInfo64.dll"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete ignoreversion

[Registry]
Root: HKCR; Subkey: "*\shell\{#AppName}"; Flags: deletekey
Root: HKCU; Subkey: "Software\Classes\*\shell{#AppName}"; Flags: deletekey
Root: HKCU; Subkey: "Software\{#AppName}"; Flags: uninsdeletekeyifempty
Root: HKCU; Subkey: "Software\{#AppName}"; ValueName: "Path"; ValueType: String; ValueData: "{app}"; Flags: uninsdeletevalue

[Icons]
Name: "{usersendto}\{#AppName}"; Filename: "{app}\{#AppName}.exe"; WorkingDir: "{app}"
Name: "{group}\{#AppName}"; Filename: "{app}\{#AppName}.exe"; WorkingDir: "{app}"
Name: "{commondesktop}\{#AppName}"; Filename: "{app}\{#AppName}.exe"; WorkingDir: "{app}"
Name: "{group}\{cm:UninstallApp}"; Filename: "{uninstallexe}"; MinVersion: 0.0,6.0;